Description: Apple Writer IIe: DOS version--Patch for the IIc
Header: Apple Writer IIe: DOS version--Patch for the IIc

 Following is the Apple Writer II Utility Program which updates, for running on
 an Apple IIc, the DOS 3.3 version of Apple Writer for the IIe only.

 To use this patch on your system, start by capturing the BASIC code listed
 below, using MacTerminal and Access II (DOS 3.3).

 Remember to capture ONLY the BASIC code portion of this message.  As an
 alternative, you could capture the entire message and then edit out the
 unwanted portions with a text editor.  Save the file as a standard DOS 3.3
 text
 file with the name PATCH.TEXT.  Type the following from the keyboard:

 EXEC PATCH.TEXT

 You will see several "]"s scroll by at this point.  When this stops and the
 cursor returns, type:

 SAVE PATCH APPLEWRITER IIE

 RUN PATCH APPLEWRITER IIE

 Insert your Apple Writer II master disk and press the Return key.  You only
 need to update your Apple Writer disk once.

 After updating your Apple Writer IIe disk, mouse characters will appear on the
 screen, but only when capital letters are shown in inverse--for example, a
 capitalized file name appearing on the data line, or when the blinking cursor
 moves over a capital letter.

 NOTE:  The utility program does not convert Apple Writer to run under ProDOS.

 100  TEXT : SPEED= 255
 105  ONERR  GOTO 500
 110  D$ =  CHR$(4): REMCTRL-D
 115  BEL$ =  CHR$(7): REMBELL
 120  CR$ =  CHR$(13): REMRETURN
 125  ESC$ =  CHR$(27): REMESCAPE
 130  NORMAL : HOME
 135  PRINT "APPLEWRITER II UTILITY PROGRAM"
 140  VTAB 4: PRINT "USE THIS PROGRAM TO UPDATE YOUR"
 145  PRINT "DOS 3.3 APPLEWRITER II FOR USE"
 150  PRINT "ON AN APPLE IIC COMPUTER."
 155  VTAB 10: PRINT "INSERT YOUR APPLEWRITER II MASTER DISK"
 160  PRINT "INTO THE DISK DRIVE AND PRESS 'RETURN' ";
 165  GET A$: IF (A$ <  > CR$) AND (A$ <  > ESC$) GOTO 165
 170  IF (A$ = ESC$) THEN  HOME : END
 175  PRINT
 200  HOME : VTAB 12: PRINT "CAREFULLY UPDATING YOUR DISK......."
 205  PRINT D$;"UNLOCK OBJ.APWRTIIE"
 210  PRINT D$;"BLOAD OBJ.APWRTIIE"
 215  GOSUB 300
 220  HOME : VTAB 12: PRINT "CAREFULLY UPDATING YOUR DISK......."
 225  PRINT D$;"BSAVE OBJ.APWRTIIE, A$1900, L$2F58"
 230  PRINT D$;"LOCK OBJ.APWRTIIE"
 235  PRINT D$;"UNLOCK OBJ.APWRTIIF"
 240  PRINT D$;"BLOAD OBJ.APWRTIIF"
 245  GOSUB 300
 250  PRINT D$;"BSAVE OBJ.APWRTIIF, A$1900, L$30D1"
 255  PRINT D$;"LOCK OBJ.APWRTIIF"
 260  HOME : VTAB 12: PRINT "YOUR DISK IS NOW UPDATED."
 265  NEW
 300  HTAB 11
 305  FOR I = 1 TO 10
 310  READ AD$,VA$
 315  A$ = AD$: GOSUB 400:DA = C
 320  A$ = VA$: GOSUB 400:DV = C
 325  PRINT ".";
 330  POKE DA,DV
 335  NEXT I: PRINT
 340  RETURN
 400  C = 0
 405  FOR X =  LEN (A$) TO 1 STEP  - 1
 410  B$ =  MID$ (A$,X,1)
 415  IF B$ = "A" THEN K = 10: GOTO 450
 420  IF B$ = "B" THEN K = 11: GOTO 450
 425  IF B$ = "C" THEN K = 12: GOTO 450
 430  IF B$ = "D" THEN K = 13: GOTO 450
 435  IF B$ = "E" THEN K = 14: GOTO 450
 440  IF B$ = "F" THEN K = 15: GOTO 450
 445  K =  VAL (B$)
 450  C = C + 16 ^ ( LEN (A$) - X) * K
 455  NEXT X
 460  RETURN
 500  HOME : VTAB 11: PRINT BEL$
 505  IF ( PEEK (222) <  > 4) GOTO 515
 510  PRINT "YOUR DISK MUST NOT": PRINT "BE WRITE PROTECTED!":
     GOTO 520
 515  PRINT "I/O ERROR!": RESTORE
 520  FOR D = 0 TO 1000: NEXT : REMDELAY
 520  GOTO 130
 600  REMDATA IS IN FORMAT OF HEX ADDRESS FOLLOWED
 601  REMBY THE NEW VALUE
 605  DATA2EC0,F2,2ED4,FA,2EB7,F6,2E98,EC,2E94,F5
 610  DATA417F,ED,4185,EC,418B,F0,4191,F4,4197,E6
 615  DATA3017,F2,302B,FA,300E,F6,2FEF,EC,2FEB,F5
 620  DATA42F8,ED,42FE,EC,4304,F0,430A,F4,4310,E6
 Apple Technical Communications


 Keywords: