Newsgroups: comp.sys.apple2
Path: news.weeg.uiowa.edu!news.uiowa.edu!hobbes.physics.uiowa.edu!math.ohio-state.edu!magnus.acs.ohio-state.edu!csn!col.hp.com!news.dtc.hp.com!hpscit.sc.hp.com!cupnews0.cup.hp.com!tribby
From: tribby@cup.hp.com (Dave Tribby)
Subject: Re: Unix BSQ
Sender: news@cupnews0.cup.hp.com (News Admin)
Message-ID: <CAH3oH.6L5@cup.hp.com>
Date: Tue, 20 Jul 1993 17:09:53 GMT
Reply-To: tribby@cup.hp.com (Dave Tribby)
References: <Jul.20.09.47.48.1993.29977@trident.usacs.rutgers.edu>
Nntp-Posting-Host: hpindhx.cup.hp.com
Organization: HP Info Networks Div/Cupertino CA
X-Newsreader: TIN [version 1.2 PL0.7]
Lines: 66

Steve Craft (scraft@trident.usacs.rutgers.edu) wrote:
> I saw nulib 3.03 on wuarchive.  I want to take those files and make them
> into something that will turn BINSCII into SHK files in my unix account.

> How to do it?  Thanks.

You also need to get hold of sciibin, which should be available on "the
usual" ftp systems.

Here's a little csh script that I pipe comp.binaries.apple2 files into
from my newsreader (tin). I just tag all the parts of the bsc archive
then pipe them into applearchive. sciibin and nulib work great together!

-- Dave Tribby (tribby@cup.hp.com  GEnie: D.TRIBBY)

------------------- csh script begins below this line ------------------
#!/bin/csh -f

# csh command file to handle Apple II archives as stdin
#
# Written by Dave Tribby   *   March 1993

#   NO parameters should be provided
if ($#argv > 0) then
   echo "usage: $0 < archive    or   cat archive.1 [archive.2 ... ] | $0"
   exit 1
endif

# Do the work in the designated archive directory
cd ~/.dave/apple/new

sciibin 
set error = $status
if ( $error != 0 ) then
      echo "{$0}: sciibin reports error status $error"
      exit 1
endif
   
set archive = `ls -t | head -1` 
echo "Created archive `pwd`/$archive"

#####
# Check for binary header format (.BXY suffix)
if ($archive =~ *.[Bb][Xx][Yy]) then
      echo "Removing binary wrapper from $archive"
      nulib bxv $archive
      set error = $status
      if ( $error != 0 ) then
         echo "{$0}: nulib reports error status $error"
      endif
      set archive = `ls -t | head -1`
      echo "Created archive `pwd`/$archive"
endif
#####

# Print table of contents
nulib tv $archive 
set error = $status
if ( $error != 0 ) then
      echo "{$0}: nulib reports error status $error"
endif

exit 0