3D0G
NEW
REM THIS IS AN APPLESOFT PROGRAM, NOT A GW-BASIC PROGRAM.
10  REM ADT 1.22 CONFIGURATION
20  REM P. GUERTIN, 1994-10-13
30  REM
40 D$ =  CHR$ (4)
50 IF PEEK(104) = 64 THEN 60
53 POKE 103,1: POKE 104,64:POKE 16384,0
55 PRINT : PRINT "RELOADING AT $4000..."
57 PRINT D$"RUN ADT CONFIGURATION"
60 F$ = "ADT": REM  ADT FILENAME
70 L$ = "$AF0": REM   ADT LENGTH
80  TEXT : HOME : SPEED= 255
90  INVERSE : PRINT " ADT 1.22 ";
100  NORMAL : PRINT "  DEFAULT CONFIGURATION"
110  VTAB 2: PRINT "----------------------------------------";
120  POKE 34,3: HOME
130  PRINT "LOADING FILE "F$"."
140  ONERR  GOTO 640
150  PRINT D$"BLOAD"F$",A$803"
160  ONERR  GOTO 650
170  PRINT
180  INPUT "DISK SLOT (1-7): ";A$:A =  VAL (A$)
190  IF A < 1 OR A > 7 THEN  PRINT "RANGE ERROR.": GOTO 180
200 V(0) = A - 1
210  INPUT "DISK DRIVE (1-2): ";A$:A =  VAL (A$)
220  IF A < 1 OR A > 2 THEN  PRINT "RANGE ERROR.": GOTO 210
230 V(1) = A - 1
240  INPUT "SSC SLOT (1-7): ";A$:A =  VAL (A$)
250  IF A < 1 OR A > 7 OR A = V(0) THEN  PRINT "RANGE ERROR.": GOTO 240
260 V(2) = A - 1
270  INPUT "SSC SPEED (300-19200): ";A$:A =  VAL (A$)
280 V(3) =  - 1
290  IF A = 300 THEN V(3) = 0
300  IF A = 1200 THEN V(3) = 1
310  IF A = 2400 THEN V(3) = 2
320  IF A = 4800 THEN V(3) = 3
330  IF A = 9600 THEN V(3) = 4
340  IF A = 19200 THEN V(3) = 5
350  IF V(3) =  - 1 THEN  PRINT "RANGE ERROR.": GOTO 270
360  INPUT "READ RETRIES (0-5, 10, 99): ";A$:A =  VAL (A$)
370  IF A = 10 THEN A = 6
380  IF A = 99 THEN A = 7
390  IF A < 0 OR A > 7 THEN  PRINT "RANGE ERROR.": GOTO 360
400 V(4) = A
410  INPUT "WRITE RETRIES (0-5, 10, 99): ";A$:A =  VAL (A$)
420  IF A = 10 THEN A = 6
430  IF A = 99 THEN A = 7
440  IF A < 0 OR A > 7 THEN  PRINT "RANGE ERROR.": GOTO 410
450 V(5) = A
460  INPUT "USE RWTS CHECKSUMS (Y/N): ";A$
470  IF A$ = "Y" THEN V(6) = 0: GOTO 500
480  IF A$ = "N" THEN V(6) = 1: GOTO 500
490  PRINT "RANGE ERROR.": GOTO 460
500  INPUT "ENABLE SOUNDS (Y/N): ";A$
510  IF A$ = "Y" THEN V(7) = 0: GOTO 540
520  IF A$ = "N" THEN V(7) = 1: GOTO 540
530  PRINT "RANGE ERROR.": GOTO 500
540  PRINT : INPUT "S)AVE, R)ESTART, Q)UIT? ";A$
550  IF A$ = "S" THEN 590
560  IF A$ = "R" THEN 80
570  IF A$ <  > "Q" THEN 540
580  GOTO 630
590  PRINT : PRINT "SAVING FILE "F$"."
600  FOR I = 0 TO 7: POKE 2054 + I,V(I): NEXT
610  PRINT D$"BSAVE"F$",A$803,L"L$
620  PRINT : PRINT "FILE "F$" SAVED."
630  POKE 216,0: TEXT : END
640  PRINT "ERROR: FILE "F$" NOT FOUND!": END
650  PRINT "UNEXPECTED ERROR. SORRY.": END
SAVE ADT CONFIGURATION,S6,D1